Visual Basic以友好易学的可视化开发环境闻名于世，成为人们学习计算机编程的首选语言。目前，全世界大概有300多万人使用着Visual Basic语言。如果您想在这茫茫众生中出类拔萃，那么您就不得不学习 API（Application Program Interface,即Windows的应用程序编程接口）编程。不懂API,那可成不了高手。
VB的API编程精粹
Visual Basic以友好易学的可视化开发环境闻名于世，成为人们学习计算机编程的首选语言。目前，全世界大概有300多万人使用着Visual Basic语言。如果您想在这茫茫众生中出类拔萃，那么您就不得不学习 API（Application Program Interface,即Windows的应用程序编程接口）编程。不懂API,那可成不了高手。
第一节：API基础
API说到底就是一系列的底层函数，是系统提供给用户用于进入操作系统核心，进行高级编程的途径。通过在 Visual Basic 应用程序中声明外部过程就能够访问 Windows API （以及其它的外部 DLLs）。在声明了过程之后，调用它的方法与调用 Visual Basic 自己的过程相同。要声明一个 DLL 过程，需要在代码窗口的“声明”部分增加一个 Declare 语句，如果该过程返回一个值，应将其声明为 Function。例如：
Declare Function publicname Lib “libname”[Alias “alias”] [([[ByVal] variable [As type] [,[ByVal] variable [As type]]...])] As Type
如果过程没有返回值，可将其声明为 Sub。
缺省情况下，在标准模块中声明的 DLL 过程，可以在应用程序的任何地方调用它。在其他类型的模块中定义的 DLL 过程是模块私有的，必须在它们前面加上 Private 关键字，以示区分。特别提请注意的是，在 32 位的 Visual Basic 中过程名是区分大小写的。而在以前的 16 位版本中并不区分大小写，这是初学者容易出错的地方。
Declare 语句中的 Lib 子句用来告诉 Visual Basic 如何找到包含该过程的 .dll 文件。如果引用的过程属于 Windows 核心库（User32、Kernel32 或 GDI32），则可以不包含文件扩展名。例如：
Declare Function GetTickCount Lib "kernel32" Alias "GetTickCount" () As Long。对于其它 DLL，Lib 子句须指定文件的路径及扩展名。
如果调用的 Windows API 过程要使用字符串，那么在声明语句中必须增加一个 Alias 子句，以指定正确的字符集。包含字符串的 Windows API 函数实际有两种格式：ANSI格式 和 Unicode格式。因此，在 Windows 头文件中，每个包含字符串的函数都同时有 ANSI 版本和 Unicode 版本。
例如，下面是 SetWindowText 函数的两种 C 语言描述。可以看到，第一个描述将函数定义为 SetWindowTextA，尾部的“A”表明它是一个 ANSI 函数：
SetWindowTextA(HWND hWnd,LPCSTR lpString);
第二个描述将它定义为 SetWindowTextW，尾部的“W”表明它是一个 Unicode 函数：
SetWindowTextW(HWND hWnd,LPCWSTR lpString);
因为两个函数实际的名称都不是“SetWindow-Text”，要引用正确的函数就必须增加一个 Alias 子句:
Private Declare Function SetWindowText Lib “user32”Alias “SetWindowTextA” (ByVal hwnd As Long, ByVal lpString As String) As Long
请注意，Alias 子句后面的字符串必须是过程的真正名称，必须是区分大小写的。事实上，您只需要记住，只有 Windows NT 才支持 Unicode 格式，而 Windows 95 只支持ANSI格式就行了。至于两者的区别，作一般的应用程序开发是不需要了解的。
VB5专业版在VB目录的\Winapi子目录下，用几个文件提供了关于API的信息。Win32api.txt文件中包含了32位Windows API函数中用到的函数和类型的结构声明以及全局常量的值。用户可以用VB本身带的外接程序“API浏览器”来方便地使用Win32api.txt,如下图所示：
点击菜单文件项的“加载文本文件...”从VB目录下的WINAPI目录中选择“WIN32API.TXT”，就可以查看WINDOWS 95系统的API函数的声明、常数定义和数据类型了。例如，我们打算查看函数InverRect（）的声明。首先，点击“搜索”按钮，输入字符串“InverRect”。在“可选项”栏中，兰色的亮度条将移动到“InverRect”项上。再点按“添加”按钮，在“选定项”中就出现“InverRect”在Visual Basic中的声明了。接下来自然是点按“复制”按钮，然后将窗口切换到Visual Basic开发环境中，在需要声明API函数的地方Ctrl+V（粘贴）即可。
上面所讲的声明方法虽然简单，但只有使用WINDOWS本身的API函数才能这样。对于第三方提供的动态链接库（DLL）您只有用键盘老老实实地敲了。
第二节：牛刀小试
现在读者一定很想自己亲自试一下，下面举两个实际应用的例子让大家体会一下API的妙用吧！
1． 使一个窗体始终保持在屏幕的最上面
我们知道VB本身自带的函数是难以完成此功能的，我们可以通过调用 Windows 的API函数：SetWindowPos达到我们的要求。操作步骤如下：
(a) 启动VB5建立一个新工程，在该工程中添加一个模块（Moudel），在该模块中用上述的“API浏览器”添加如下的该API函数的函数声明和常量声明部分：
'API函数声明
Declare Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal x As Long, ByVal y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
'常量声明：
Global Const SWP_HIDEWINDOW = &H80
Global Const SWP_NOACTIVATE = &H10
Global Const SWP_NOCOPYBITS = &H100
Global Const SWP_NOMOVE = &H2
Global Const SWP_NOOWNERZORDER = &H200
Global Const SWP_NOREDRAW = &H8
Global Const SWP_NOREPOSITION = SWP_NOOWNERZORDER
Global Const SWP_NOSIZE = &H1
Global Const SWP_NOZORDER = &H4
Global Const SWP_SHOWWINDOW = &H40
Global Const HWND_BOTTOM = 1
Global Const HWND_BROADCAST = &HFFFF&
Global Const HWND_DESKTOP = 0
Global Const HWND_NOTOPMOST = -2
Global Const HWND_TOP = 0
Global Const HWND_TOPMOST = -1
Global Const Flags = SWP_NOMOVE Or SWP_NOSIZE
这里以“SWP_”开头的常量是表示窗体所具有的风格，这些常量可以通过VB中的“OR”操作符组合在一起。而以“HWND_”开头的常量表示窗体在桌面上的位置。从这些常量的英文单词的意义上读者应该很容易理解他们所具有的风格了。所以笔者就不一一去说明了。至于为什么要添加这些常量而不是别的这就要您去查看Windows SDK关于该函数的帮助文档了。当然这对于初学者来说有一定的难度，但不要畏惧，只要您仔细看帮助就会慢慢搞懂的。因为这些API函数是为C和C++的编程人员编写的，所以如果您懂一点C++的话会很容易理解的。
(b) 现在只要在您想要此功能的地方调用该函数就可以了，调用的方法如下：
Dim Success as Long
Success=SetWindowPos(me.HWnd, HWND_TOPMOST,0,0,0,0, FLAGS)
若Success返回的值不等于零则表示调用成功。
比如在某个窗体的Load事件中加入上述的两行代码，就可以达到使该窗体始终位于屏幕最上面的目的。
细心的读者可能已经发现上面的例子中的模块声明中声明了好几个常量，可为什么只用到三个呢？现在您可以试着改变一下API函数“SetWindowPos”中的第二个参数或常量FLAGS中的项，看看您的窗体会出现什么样的效果?
2. VB5中如何屏蔽掉win95中的CTRL_ALT_DEL，CTRL_ESC，ALT_TAB三组热键
通过调用API函数“SystemParametersInfo”来实现。
首先创建一新工程；在此工程中添加一个窗体和一个模块；在窗体上拖放两个按钮分别命名为“cmdDisable”，“cmdEnable”;Copy如下代码入模块中：
Public Declare Function SystemParametersInfo Lib “user32”Alias “SystemParametersInfoA”(ByVal uAction As Long, ByVal uParam As Long, lpvParam As Any, ByVal fuWinIni As Long) As Long
Public Const SPI_SCREENSAVERRUNNING = 97
在窗体的代码编辑区Copy如下代码：
'使三组热键失效
Private Sub cmdDisable_Click()
SystemParametersInfo SPI_SCREENSAVERRUNNING, True, ByVal 1&, 0
End Sub
'使热键有效
Private Sub cmdEnable_Click()
SystemParametersInfo SPI_SCREENSAVERRUNNING, False, ByVal 1&, 0
End Sub
Private Sub Form_Unload(Cancel As Integer)
'程序退出前是热键有效
cmdEnable_Click
End Sub
若将此功能和屏幕保护程序结合到一起，那您的屏幕保护程序一定增色许多。
API函数的简单调用例子就是这么容易，相信现在您对API的调用已不再感到神秘了，接下来我们就看看一个比较复杂的应用。
第三节：高手进阶
上面的关于API的调用的例子只是为了带您去Windows API世界中去探索一下。相信您已探索到了一点眉目并想去实现一些更“好玩”的东西了。好！下面就向您介绍一个很“好玩”同时又会使您的程序看起来更专业化的一个API调用。
相信您的机器上一定装有“金山词霸”，试着启动它您发现了什么？启动画面过后它“不见了”。把鼠标移到桌面的右下角，原来它以图标的形式“藏在”Windows的托盘中。用鼠标右击它还会弹出一个菜单功能项供您选择。现在您一定想把自己的程序也放到托盘，这样您的程序多具有专业水准！
下面是此功能的实现步骤：
1．这里我们调用的API函数是：“Shell_NotifyIcon”，在您的模块中添加如下的函数声明和常量声明：
'以下常量告诉系统在托盘中您的图标上发生了什么操作
'常量声明
Public Const WM_MOUSEISMOVING = &H200 '在图标上移动鼠标
Public Const WM_LBUTTONDOWN = &H201 '鼠标左键按下
Public Const WM_LBUTTONUP = &H202 '鼠标左键释放
Public Const WM_LBUTTONDBLCLK = &H203 '双击鼠标左键
Public Const WM_RBUTTONDOWN = &H204 '鼠标右键按下
Public Const WM_RBUTTONUP = &H205 '鼠标右键释放
Public Const WM_RBUTTONDBLCLK = &H206 '双击鼠标右键
Public Const WM_SETHOTKEY = &H32 '响应您定义的热键
'API 函数声明
Public Declare Function Shell_NotifyIcon Lib "shell32" Alias "Shell_NotifyIconA" (ByVal dwMessage As enm_NIM_Shell, pnid As NOTIFYICONDATA) As Boolean
'自定义一个调用API Shell_NotifyIcon 要用到的类型“NOTIFYICONDATA”
Public Type NOTIFYICONDATA
cbSize As Long 'NOTIFYICONDATA类型的大小
hwnd As Long '您的应用程序窗体的句柄
uId As Long '应用程序图标资源的ID号
uFlags As Long '使那些参数有效它是以下枚举类型中的‘NIF_MESSAGE 、NIF_ICON、NIF_TIP三者的组合
uCallbackMessage As Long '鼠标移动时把此消息发给该图标的窗体
hIcon As Long '图标句柄
szTip As String * 64 '当鼠标在图标上时显示的Tip文本
End Type
'这是一个枚举类型它告诉API Shell_NotifyIcon 去做什么操作
Public Enum enm_NIM_Shell
NIM_ADD = &H0 '在“金碟”中加一图标
NIM_MODIFY = &H1 '修改“金碟”中的图标
NIM_DELETE = &H2 '删除“金碟”中的图标
NIF_MESSAGE = &H1 '使类型“NOTIFYICONDATA”中的uCallbackMessage有效
NIF_ICON = &H2 '使类型“NOTIFYICONDATA”中的hIcon有效
NIF_TIP = &H4 '使类型“NOTIFYICONDATA”中的szTip有效
WM_MOUSEMOVE = &H200 '使鼠标移动消息有效
End Enum
'定义一个“NOTIFYICONDATA”类型的变量
Public nidProgramData As NOTIFYICONDATA
以上是函数及常量声明和自定义的一个类型变量，下面是此API函数的调用方法：
2． 在窗体上用菜单编辑器编辑一个具有如下信息的菜单项：
主菜单：无标题、名称（mainMenu）
子菜单：标题（API编程）、名称（submnu1）；
标题（退出）、名称（submnu2）。
这里只是举个例子，具体的功能项您可以根据您的具体需要来编辑此菜单项。
3．在窗体的Load事件中添加如下代码：
Private Sub Form_Load()
'隐藏窗体
With Me
.Top = -10000
.Left = -10000
.WindowState = vbMinimized
End With
'设置类型NOTIFYICONDATA所具有的特征
With nidProgramData
.cbSize = Len(nidProgramData)
.hwnd = Me.hwnd
.uId = vbNull
.uFlags = NIF_ICON Or NIF_TIP Or NIF_MESSAGE
'触发鼠标移动消息
.uCallbackMessage = WM_MOUSEMOVE
.hIcon = Me.Icon '“托盘”中放入窗体图标，您可以把窗体的图标换成您所喜欢的图标
.szTip = "VB的Win32 API编程" & vbNullChar
End With
'调用该函数
Shell_NotifyIcon NIM_ADD, nidProgramData
End Sub
'根据不同的鼠标消息做不同的操作
Private Sub Form_MouseMove(Button As Integer, Shift As Integer, x As Single, Y As Single)
On Error GoTo Form_MouseMove_err:
Dim Result As Long
Dim msg As Long
'X的值依赖与显示模式的设置
If Me.ScaleMode = vbPixels Then
msg = x
Else
msg = x / Screen.TwipsPerPixelX
End If
Select Case msg
Case WM_LBUTTONUP
' 在这里加入鼠标左键释放时您想做的操作
Case WM_LBUTTONDBLCLK
' 在这里加入双击鼠标左键时您想做的操作
Case WM_RBUTTONUP
'通常这里弹出您的功能菜单
PopupMenu mainMenu
Case WM_MOUSEISMOVING
' 在这里加入鼠标正在移动时您想做的操作
End Select
Exit Sub
Form_MouseMove_err:
'在这里加入您的处理异常错误的代码
End Sub
4.Run您的程序，您是不是看到了象“金山词霸”一样的功能？相信您此时的感觉一定特别“爽”！
API的世界是丰富多彩的，只要您肯细心地去探索它您一定会获得许多意想不到的好东西。所以笔者觉得它值得每一个具有“好奇“精神的人去探索它。后续的期刊笔者会向读者详细介绍一些更好更“牛”的API调用。